Logicwurks Home Page

Links To Excel Code Examples

Tracing VBA Statements
Range/Wkb/Wks Variables
Add Grand Totals Using Ranges
Using Range Offset Property
Using Range Find Method
ConvertCellAddressToRange
Set Conditional Formatting
Union Of Ranges
Parse Range Strings
Delete Duplicate Rows
Delete Rows And Columns
Worksheet Variables
TypeName And TypeOf
Loop Through Worksheets
Loop Through Open Workbooks
Form Button Magic
Command Button Magic
Add Worksheets Dynamically
ImportExternalWorksheets
Find Last Row Or Column
Copy And Paste Special
Copy To Specific Cell Types
Range Copy With Filter
ExcelFileOpenSaveClose
ExcelFileOpenSaveCSV
Open An Excel File
Open An Excel File w/Params
Open An Excel File On Web
Save A Workbook
Save A Workbook Using mso
Clone A Workbook
Test If WEB URL Exists
Parse Using Split Command
Using Classes in Excel
TypeStatementStructures
Color Management
Convert Cell Color To RGB
Sort Methods 2003 - 2010
Sort Alpha/Numeric In ASCII
Search Using Match Function
Search Using Vlookup Function
Search Using Xlookup Function
Using Find Instead of Vlookup
Remove String Non-Printables
Auto_Open And Auto_Close
Initialize Form At Open
Edit Numerics In UserForm
Load Combo And List Boxes
Floating Sheet Combo Boxes
Advanced User Form Coding
Excel Events
Worksheet Change Events
Binary Search Of Array
Typecast Constants
Excel Error Handling
Handling Optional Parameters
Data Validation Drop Downs
Insert Data Validation Sub
Read A Text File w/Handle
Write A Text File w/Handle
Read a Binary File w/Handle
Update a Binary File w/Handle
Binary File Copy and Update
Read A Text Fiile w/Script
Text File Processing Examples
Test For Exists Or Open
Splash Screen
Dynamically Load Formulas
PaymentStreamsByDate
Date Examples
Date Find Same Days
Convert Month To Number
Initialize Arrays
Load Arrays Using Evaluate
ChartsAndGraphsVBA
Redim An Array
Reassign Button Action
Timer Functions
Legacy Calendar Control
Excel 2010 Date Picker
Date Picker Alternative
Generate Multiple Worksheets
Read Access Data Into Excel
Send Outlook Email w/Attach
Copy AutoFilters To Sheets
Export A Text File
Get Windows User Name
VBA Format Statement
Manipulate Files via VBA
Dynamically Load Images
Loop Through Worksheet Objects
Loop Through Form Objects
Loop Through Files with DIR
Active-X Checkboxes
Add Forms Checkboxes Dynam
Paste Pictures Into Excel
Copy Pictures Sheet To Sheet
Copy Pictures Sheet To Sheet
Create Forms Buttons With VBA
Extract Filename From Path
Convert R1C1 Format to A1
Special Cells Property
Insert Cell Comments

Links To Access Code Examples

DAO Versus ADODB
SearchVBACodeStrings
Interface Excel With Access
Create Form Manually
Create Recordset With AddNew
Multi-Select List Boxes
Update Field(s) In A Recordset
Update Excel Pivot From Access
Import A Tab Delimited File
Export Excel FileDialog
Create Excel Within Access
Open Excel Within Access
Open Excel OBJ From Access
Format Excel From Access
Control Excel via Access VBA
On Error Best Practices
Import Tab Delim w/WinAPI
Initialize Global Variables
Using TempVars For Globals
Access Error Handling
Loop Through Form Controls
Insert A Calendar Control
Create A Filtered Recordset
Populate Combo Boxes
Bookmarks And Forms
Combo Box Multiple Sources
Passing Form Objects
Create VBA SQL Statements
Create Dynamic Queries
Display File Images On A Form
Manipulate Files via VBA
Manipulate Files via Scripting
Number Subform Records
Reference Subform Objects
Parse Delimited Fields
Parameterized Queries (VBA)
Manipulating QueryDefs In VBA
FindFirst On Combined Keys
Dlookup Command
Dlookup In Form Datasheet
Execute SQL Delete Records
Commit Form To Table
Report With No Data
Reference Form Objects
DSNLess Connections To MySQL
Print Active Form Record
Count Records in Linked Tables
Delete Empty Tables
Open Linked SQL Tables

 

Parse A Delimited Excel String Using the Split Function

This program demonstrates how to take "space delimited" strings in Column A and parse them into separate columns. For example, the string "abc def ghi jkl mno" in any row in Column A would be transformed to a different worksheet starting in Column A as follows:

Column A = abc
Column B = def
Column C = ghi
Column D = jkl
Column E = mno

This program also demonstrates opening a file with a File Open Dialog box.

Program Code

Option Explicit
Option Compare Text

' ************************************************
' Variables For File Open Dialogue Box
' ************************************************
Public strDialogueFileTitle As String
Public strFilt As String
Public intFilterIndex As Integer
Public strCancel As String
Public strWorkbookNameAndPath As String

Public Sub FormatCutList()
' ******************************************************************
' Workbook and Worksheet Variables
' ******************************************************************
Dim wkbFormatterTemplate As Workbook
Dim wksSplitView As Worksheet
Dim wkbFabtrolScreenScrape As Workbook
Dim wksFabtrolScreenScrape As Worksheet

' ******************************************************************
' Other Variables For the Split Processing
' ******************************************************************
Dim varRawString As Variant
Dim lngLastRow As Long
Dim lngCurrentActiveRow As Long
Dim rngRowsToConvert As Range
Dim C As Range
Dim varSplitArray As Variant
Dim i As Long
Dim lngSplitWorksheetRow As Long


' ********************************************************
' Turn Off Screen Updating
' ********************************************************
Application.ScreenUpdating = False

' ******************************************************************
' Set Template Workbook and Worksheet Variables
' ******************************************************************
Set wkbFormatterTemplate = ThisWorkbook
Set wksSplitView = wkbFormatterTemplate.Sheets("SplitView")

' ****************************************************************************
' Set Up Filters For Which Files Should Show In The Open File Dialog Box
' ****************************************************************************
strFilt = "Excel 2000 Files (*.xls),*.xls," & _
          "Excel 2007 And Later (*.xlsx),*.xlsx,"

' ****************************************************************************
' Set Up The Prompt In The Dialogue Box
' ****************************************************************************
intFilterIndex = 1
strDialogueFileTitle = "Select The Excel PDF Screen Scrape File"

' ****************************************************************************
' Present the Open File Dialogue To The User
' ****************************************************************************
Call OpenFileDialogue

' ****************************************************************************
' Notify The User If No File Was Successfully Opened
' ****************************************************************************
If strCancel = "Y" Then
    MsgBox ("An Open Error Occurred Importing Your File Selection")
    Exit Sub
End If

' ********************************************************
' Save The Newly Opened Workbook And Worksheet Names
' ********************************************************
Set wkbFabtrolScreenScrape = ActiveWorkbook
Set wksFabtrolScreenScrape = wkbFabtrolScreenScrape.ActiveSheet

' ********************************************************
' Locate the Last Row in the Most Recently Opened Workbook
' ********************************************************
lngLastRow = wksFabtrolScreenScrape.Cells(Rows.Count, 1).End(xlUp).Row

If lngLastRow < 5 Then
    MsgBox ("The PDF Screen Scrape Must Be Pasted To Column 1 of an Empty Workbook")
    Exit Sub
End If

' ********************************************************
' Set the Range for the Split Processing
' ********************************************************
Set rngRowsToConvert = Range(wksFabtrolScreenScrape.Cells(1, 1), wksFabtrolScreenScrape.Cells(lngLastRow, 1))

lngSplitWorksheetRow = 0

' ********************************************************
' Cycle Through Column A To Split The Space-Delimited Data
' Source For "Un-Split" Data = Imported Excel Workbook
' Target For The Split Data = The Template Application
' ********************************************************
For Each C In rngRowsToConvert
    varRawString = C.Value
    varSplitArray = Split(varRawString, " ")
    lngSplitWorksheetRow = lngSplitWorksheetRow + 1
    For i = LBound(varSplitArray) To UBound(varSplitArray)
        wksSplitView.Cells(lngSplitWorksheetRow, i + 1) = varSplitArray(i)
    Next i
Next C

' ******************************************************************
' Close The Raw Workbook
' ******************************************************************
wkbFormatterTemplate.Activate
Application.DisplayAlerts = False
wkbFabtrolScreenScrape.Close Savechanges:=False
Application.DisplayAlerts = True

wksSplitView.Select
wksSplitView.Cells(1, 1).Select

' ********************************************************
' Turn On Screen Updating
' ********************************************************
Application.ScreenUpdating = True

End Sub
Sub OpenFileDialogue()

' ************************************************
' Display a File Open Dialogue Box For The User
' ************************************************
strCancel = "N"
strWorkbookNameAndPath = Application.GetOpenFilename _
    (FileFilter:=strFilt, _
     FilterIndex:=intFilterIndex, _
     Title:=strDialogueFileTitle)
   
' ************************************************
' Exit If No File Selected
' ************************************************
If strWorkbookNameAndPath = "" Then
    MsgBox ("No Filename Selected")
    strCancel = "Y"
    Exit Sub
ElseIf strWorkbookNameAndPath = "False" Then
    MsgBox ("You Clicked The Cancel Button")
    strCancel = "Y"
    Exit Sub
End If

' ******************************************************
' Now That You Have The User Selected File Name, Open It
' ******************************************************
Workbooks.Open strWorkbookNameAndPath

End Sub