Using Timers to Improve Performance
If you have several alternatives to accomplish the same programming objective, it is sometimes useful to model each method and see the actual time it takes to run. The "Timer" function of Excel provides the number of seconds elapsed since Midnight at the instant the Timer function is executed. By subtracting the beginning timer value from the ending timer value, elapsed time can be measured. This is a very useful way to determine the the most efficient technique to accomplish a mission such as: MATCH vs. VLOOKUP, array sorts vs. worksheet sorts, and hundreds of other examles.
The following simple example shows how to time a loop that occurs 250 million times.
Program Code
Option Explicit
Option Base 1
Sub ExampleOfUsingTimer()
Dim i As Long
Dim j As Long
Dim dteStartTime As Single
Dim dteEndTime As Single
Dim dblSum As Double
dblSum = 0
' ****************************************************************
' Use The Timer Function To Measure the Length Of Time for Loops
' ****************************************************************
dteStartTime = Timer
For i = 1 To 500000
For j = 1 To 500
dblSum = dblSum + 1
Next j
Next i
dteEndTime = Timer
MsgBox ("Run Time = " & dteEndTime - dteStartTime & " Seconds" & vbCrLf & _
"And The Number Of Loops is " & dblSum)
End Sub
Using Timers to Close A Workbook After Inactivity
The following example shows how to close a workbook if there is no activity. At the Workbook_Open event, a timer starts. If the time exceeds a certain value, the workbook is saved and closed. In the Worksheet_Change event section, any keystroke will reset the timer so that the countdown to the save and close starts again.
Program Code
' %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
' This Goes in the Workbook Class Section
' %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
Option Explicit
Private Sub Workbook_Open()
' ***************************************************
' When The Workbook Opens, Start The Timer
' ***************************************************
Call StartTimer
End Sub
' %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
' This Goes in the Worksheet Class Section
' %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
' ***********************************************************
' If A Keystroke Is Detected, Turn Off The Timer
' Then Reset It Again For The Time To Close and Save Workbook
' ***********************************************************
Call StopTimer
Call StartTimer
End Sub
' %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
' This Goes in the General Modules Section
' %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
Option Explicit
Public TimeToClose
Sub StartTimer()
' ******************************************************************
' This Starts The Countdown For Inactivity... Change the 2 Minutes
' Below To Any Time You Require
' ******************************************************************
TimeToClose = Now + TimeValue("00:02:00")
Application.OnTime TimeToClose, "SaveAndCloseWorkbook", , True
End Sub
Sub SaveAndCloseWorkbook()
' ******************************************************************
' When The Period of Inactivity is Detected, Save And Close The
' Workbook
' ******************************************************************
ThisWorkbook.Close SaveChanges:=True
End Sub
Sub StopTimer()
' ******************************************************************
' This Stops The Timer
' ******************************************************************
Application.OnTime TimeToClose, "SaveAndCloseWorkbook", , False
End Sub
Using Timers to Increment A Cell Counter
This simple example shows how to increment the contents of a cell every 5 seconds.
Program Code
' ************************************************************
' Initiated from a Button (General Module)
' ************************************************************
Option Explicit
Public Sub Stop_Timer()
Application.OnTime RunWhen, "msgticker", , False
End Sub
' ************************************************************
' At Worksheet Open Time (General Module)
' ************************************************************
Option Explicit
Public Sub Auto_Open()
' *****************************************
' Start Timer
' *****************************************
msgticker
End Sub
' ************************************************************
' Called From Other Routines (General Module)
' ************************************************************
Public RunWhen
Public intCellValue As Integer
Sub msgticker()
RunWhen = Now + TimeValue("00:00:05")
intCellValue = intCellValue + 1
Cells(1, 1).Value = intCellValue
Application.OnTime RunWhen, "msgticker", , True
End Sub